$nav
===== Function: llAttachToAvatar =====

<code lsl2>
llAttachToAvatar(integer attachment_point)
</code>

Adds an inworld object to the given attachment point of the avatar who has [[constants/PERMISSION_ATTACH]] permissions (currently only allowed for owner).

===== Parameters =====

=== attachment_point ===
The attachment point to attach to. Zero (0) means the last attachment point the object was attached to (if the object wasn't previously attached, it defaults to Right Hand). The following constants can also be used:

{{page>constants/attach/tpl}}

===== Notes =====

  * This function only works for attaching to the owner of the object.
  * The attachments are added, not replaced.
  * An attached object can't be attached to a different attachment point; the function will silently fail.
  * Permissions are a requisite; if the script doesn't request them, an error will be said (i.e. 20m range) in [[constants/DEBUG_CHANNEL]]: "Cannot find the agent to attach to."
  * If permissions were requested but not granted, it will send an error to the owner only in **DEBUG_CHANNEL**: "Script trying to attach to owner but PERMISSION_ATTACH permission not set!" (confusingly, this error is also shown if the permissions were requested to someone other than the owner). Scripts can't hear this error.
  * If permissions were granted to someone other than owner, when calling this function an error will be said (i.e. 20m range) in **DEBUG_CHANNEL**: "Script trying to attach to someone other than owner!"
  * The **PERMISSION_ATTACH** permission is revoked only when the object changes owner, when the granter responds to a new permission request from the same script that doesn't include it or responds by denying it, or when the script is reset. There's nothing the granter can do on his/her own to revoke them, if the script doesn't do another request.

===== Short examples =====

<code lsl2>
llAttachToAvatar(0); // attaches the object to the default attachment point
// (assuming permissions are granted for the owner,
// the object isn't already attached and the owner is in sim)

llAttachToAvatar(ATTACH_REAR); // attaches to the right ear (nothing to do with the bum)

llAttachToAvatar(14); // same as above
</code>

===== Complete examples =====

This script requests permissions on touch and attaches to the default attachment point if granted:

<file lsl2 llAttachToAvatar-example.lsl>
default
{
    touch_start(integer n)
    {
        if (llDetectedKey(0) != llGetOwner())
        {
            llRegionSayTo(llDetectedKey(0), 0, "Not possible to attach to you, sorry.");
            return;
        }
        // Request permission to attach from owner. We'll attach if granted.
        llRequestPermissions(llGetOwner(), PERMISSION_ATTACH);
    }

    run_time_permissions(integer perms)
    {
        if (perms & PERMISSION_ATTACH)
            llAttachToAvatar(0);
        else
            llOwnerSay("Attach permission request denied, not attaching");
    }
}
</file>

===== See also =====

  * [[llAttachToAvatarTemp]] is similar, but the attached object disappears when detached or on logout and doesn't go to the receiver's inventory; in other words, the attach is temporary. It also allows attaching to avatars other than the owner.
  * [[events/attach]] event is generated when an object is attached or detached.
  * [[llRequestPermissions]] is used to requests permissions from an avatar, in particular **PERMISSION_ATTACH** required by this function.
  * [[events/run_time_permissions]] event is generated when the result of the permissions request is ready.
  * [[llDetachFromAvatar]] to detach the object if attached (also requires **PERMISSION_ATTACH**).
  * [[llGetAttached]] to get the attachment point.