$nav
===== Function: llTan =====

<code lsl2>
float llTan(float arg)
</code>

Return the trigonometric tangent of the argument. The argument should be an angle in radians.

===== Parameters =====

=== arg ===
Angle whose tangent is to be found, in radians.

===== Return value =====

A [[types/float]] with the tangent of the argument.

===== Notes =====

  * Inputs of $minf, $pinf and $nan result in $nan.
  * If the angle is otherwise not between -9.22337e18 and 9.22337e18, the argument is returned unchanged.

===== Short examples =====

<code lsl2>
float F;
F = llTan(1); // Sets F to approx. 1.557408, which is the tangent of 1 radian.
F = llTan(-1); // Sets F to approx. -1.557408, because that's the tangent of -1 radian.
F = llTan(0); // Sets F to 0, because that's the tangent of 0.
F = llTan(PI); // Sets F to approximately 0, which is the tangent of PI.
               // It isn't exactly 0 because of rounding/calculation errors.
F = llTan(1e20);  // Sets F to 1e20 because 1e20 is returned unchanged.
</code>

===== Complete examples =====

The tangent gives you the slope of an angle, that is, how much you advance vertically per each unit you advance horizontally.

<file lsl2 llTan-example.lsl>
default
{
    state_entry()
    {
        llOwnerSay("Calculate the slope given the angle. Please say the angle in chat.");
        llListen(0, "", llGetOwner(), "");
    }

    listen(integer chan, string name, key id, string msg)
    {
        float angle = (float)msg * DEG_TO_RAD;
        llOwnerSay("For an input angle of " + msg + ", you climb "
                   + (string)llTan(angle) + " m per each horizontal m");
    }
}
</file>

===== See also =====

=== Related trigonometric functions ===
  * $lfn[llSin] calculates the sine of the argument.
  * $lfn[llCos] calculates the tangent of the argument.
  * $lfn[llAtan2] calculates the angle of a 2D vector.

=== Other trigonometric functions ===
  * $lfn[llAsin] calculates the inverse sine of the argument.
  * $lfn[llAcos] calculates the inverse cosine of the argument.

=== Related information ===
  * $lty[float] type and associated caveats and limitations.